''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Build a Nolf1 DEdit project for the Nolf2 demo files - by Deunid, 2002 - All rights Reserved
'
' Feel free to reuse at will except for sites competing with NolfGirl.com
'
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Dim WshShell,WshFiles
Dim location,locationDemo,locationDemoKeys,command,answer,drive,freespace,char,i
On Error Resume Next
Set WshShell = WScript.CreateObject("WScript.Shell")
Set WshFiles = WScript.CreateObject("Scripting.FileSystemObject") 
if (WshFiles is nothing) then 
	msgbox "Ooops. This PC lacks the shell scripting capabilities required." & vbCr & "Please correct the problem (I need it to be able to work)!", vbExclamation, "Create Nolf1 project Nolf2 Demo"
else
	location = WshShell.RegRead("HKLM\Software\Monolith Productions\No One Lives Forever\1.0\WorkingDirectory")
	if location = "" then
        	msgbox "Ooops. NOLF does not seem correctly installed on this PC." & vbCr & "Please correct the problem (I need it to be able to work)!", vbExclamation, "Create Nolf1 project Nolf2 Demo"
	else
		locationDemo = WshShell.RegRead("HKLM\Software\Monolith Productions\No One Lives Forever 2 (Official Demo)\1.0\InstallDir")
		if locationDemo = "" then
        		msgbox "Ooops. The NOLF2 Demo does not seem correctly installed on this PC." & vbCr & "Please correct the problem (I need it to be able to work)!", vbExclamation, "Create Nolf1 project Nolf2 Demo"
		else
			command = location & "\Tools\DEdit.exe"
			if not WshFiles.fileExists(command) then
				msgbox "Ooops. The NOLF Edition Tools do not seem installed." & vbCr & "Please correct the problem (I need them to be able to work)!", vbExclamation, "Create Nolf1 project Nolf2 Demo"
			else
				answer = msgbox("Welcome to NolfGirl's NOLF2 skinning tutorial!" & vbCr & vbCr & "I'm going to create a Nolf1 DEdit project for Nolf2's demo files", vbOkCancel, "Create Nolf1 project Nolf2 Demo")
				if answer <> vbOk then
					msgbox "Nothing was done.", vbExclamation, "Create Nolf1 project Nolf2 Demo"
				else
					locationDemoKeys = ""
					for i = 1 to len (locationDemo)
						char = mid(locationDemo,i,1)
						if char = "+" then char = "{+}"
						if char = "^" then char = "{^}"
						if char = "%" then char = "{%}"
						if char = "~" then char = "{~}"
						if char = "(" then char = "{(}"
						if char = ")" then char = "{)}"
						locationDemoKeys = locationDemoKeys & char
					next 
					msgbox "Please don't touch anything (keyboard and mouse) until I have finished!" & vbCr & vbCr & "This will take only a few seconds." & vbCr & vbCr & "Thanks!", vbOKOnly, "Create Nolf1 project Nolf2 Demo"
					command = """" & location & "\Tools\DEdit.exe"""
					WshShell.Run command, 1, FALSE
					WScript.Sleep 2000
					wshShell.SendKeys "%F"
					WScript.Sleep 200
					wshShell.SendKeys "N"
					WScript.Sleep 200
					wshShell.SendKeys locationDemoKeys & "\NOLF2DEMO{ENTER}"
					WScript.Sleep 200
					wshShell.SendKeys "{ENTER}"
					WScript.Sleep 200
					wshShell.SendKeys "{TAB}{ENTER}"
					WScript.Sleep 200
					wshShell.SendKeys "^S"
					WScript.Sleep 200
					if not WshFiles.fileExists(locationDemo & "\NOLF2DEMO\Nolf2Demo.dep") then
						msgbox "Ooops. Sorry, but something seems to have went wrong when using DEdit. Please try manually.", vbExclamation, "Create Nolf1 project Nolf2 Demo"
					else
						msgbox "Done - Project NOLF2DEMO created, I have finished! Thanks." & vbCr & vbCr & "Have a look at the Texture tab for some new stuff...", vbOKOnly, "Create Nolf1 project Nolf2 Demo"
					end if
				end if
			end if
		end if
	end if
end if